UniMixins/module-mixingasm/build.gradle

apply from: "${rootDir}/module-conventions.gradle"

dependencies {
	implementation project(path: ":module-mixin", configuration: 'unimix')
	shadow(project(":module-common")) {
		transitive = false
	}
}

archivesBaseName = archivesBaseName.replace("-1.7.10", "-mixingasm-1.7.10")

apply plugin: "com.github.johnrengelman.shadow"

shadowJar {
	archiveClassifier = 'dev'
	configurations = [project.configurations.shadow]

	relocate 'io.github.legacymoddingmc.unimixins.common', 'io.github.legacymoddingmc.unimixins.mixingasm.repackage.common'

	manifest {
		attributes (
			'TweakClass': 'org.spongepowered.asm.launch.MixinTweaker',
			'FMLCorePluginContainsFMLMod': true,
			'ForceLoadAsMod': true,
			'MixinConfigs': 'mixingasm.mixin.json',
			'TweakOrder': 0,
		)
	}
}

jar {
	dependsOn shadowJar
	enabled = false
}

ext.uniVersion = version
version += "+" + ext.extraVersion

tasks.injectTags.configure {
	outputClassName.set("io.github.legacymoddingmc.unimixins.mixingasm.Tags")
}